Entscheidungen in Excel mit der WAHL-Funktion (Teil II)

Der vorherige Beitrag zeigte, wie Zahlen, Zellbezüge und definierte Namen als Argumente in der WAHL-Funktion verwendet werden können.

Im heutigen Beitrag siehst du, wie Formeln, Funktionen und Text als Argumente eingesetzt werden können.

Formeln als Argumente

Formeln können mit Zellbezügen, aber auch mit Zahlen dargestellt werden.

Lege in B2 die Auswahlmöglichkeit für den Index an.

Schreibe in D2:D3 z.B. die Zahlen 25 und 30.

Du willst über den Index entscheiden lassen, ob die Zahlen addiert, subtrahiert, multipliziert oder dividiert werden sollen.

Schreibe in D5 diese Formel mit Zellbezügen:

=WAHL($B$2;D2+D3;D2-D3;D2*D3;D2/D3)

Das Ergebnis lautet 750. Gemäß Index = 3 wurde das dritte Argument in der WAHL-Funktion ausgewählt und die Zahlen multipliziert.

Gebe in B2 abwechselnd die anderen möglichen Auswahlen 1, 2 und 4 ein. Das Ergebnis wird jedes Mal ein anderes sein.

Schreibe in D5 nun diese Formel mit Zahlen:

=WAHL($B$2;25+30;25-30;25*30;25/30)

Die Ergebnisse entsprechen, natürlich, den vorangegangenen Ergebnissen.

Es gibt eine weitere Möglichkeit, Formeln als Argumente zu verwenden. Diesmal werden definierte Namen dazu verwendet.

Gehe jetzt einmal ins Menü Formeln / Definierte Namen und rufe „Namen definieren“ auf.

Definiere den Namen „Addition“ wie abgebildet und analog die Namen „Subtraktion“, „Multiplikation“ und „Division“.

In B8 wählst du den Index für die WAHL-Funktion aus.

In D11 schreibst du diese Formel:

=WAHL($B$8;Addition;Subtraktion;Multiplikation;Division)

Der Index ist 2, damit werden die Zahlenwerte in D8 und D9 subtrahiert.

Das Ergebnis ist -5.

Beachte, die definierten Namen sind zwar Text, werden aber nicht in Anführungszeichen geschrieben.

Funktionen als Argumente

Bereite dir in deiner Tabelle wieder vier Zellen vor, eine für den Index, zwei für Zahlenwerte und eine für die Berechnung.

Du hast dir drei Formel ausgesucht, die du in der WAHL-Funktion als Argument verwenden willst, WURZEL(), SUMME() und PRODUKT().

Schreibe in D17 z.B. diese Formel:

=WAHL($B$14;WURZEL(D14)*D15;SUMME(D14:D15);PRODUKT(D14;D15))

Gemäß Index = 1 wird WURZEL(D14)*D15 gerechnet, Ergebnis: 248,700623.

Text als Argumente

Gehe noch einmal zur Verkäuferliste im 1. Teil im Abschnitt Zellbezüge als Argumente zurück. Du willst z.B. wissen, welcher Verkäufer den dritten Rang erreicht hat. In deiner vorhandenen Liste siehst du das natürlich auf Anhieb, aber es könnten auch 254 Zeilen sein.

Schreibe in B2 den Rang, den du suchst, die 3.

In D2 schließlich gibst du diese Formel ein:

=WAHL(VERGLEICH($B$2;D3:D10;0);“Lisa“;“Bernd“;“Josefine“;“Melanie“;“Jana“;“Paul“;“Johann“;“Leo“)

Was passiert? Den Index von WAHL ermittelst du mit der VERGLEICH-Funktion. Der Index schließlich wählt den Namen des Verkäufers aus der Liste aus.

Im Beispiel hat Johann den dritten Rang belegt.

Beachte hier, dass du die Argumente, die auch Text sind, in Anführungszeichen schreiben musst.

Fazit

Die WAHL-Funktion mit bis zu 10 oder 15 Argumenten ist noch überschaubar. Wenn du wirklich 254 Argumente zur Verfügung hast, wird die Formel unendlich lang und keinen Spaß mehr machen.

Schreibst du beispielsweise die Zahlen von 254 bis 1 (rückwärts) untereinander und suchst den 133. Wert, enthält die Formel 1281 Zeichen. Aber sie funktioniert.

Die Formel sieht (auszugsweise) so aus:

=WAHL(133;M154;M155;M156; … ;M405;M406;M407)

Ergebnis: 122

Aber, wer macht schon so etwas?